**** Serie sur l'energie ****

****************************************************************;
ods pdf file="energie.pdf";
options nocenter linesize=75 pagesize=66;

data serietxt;
  infile '~duchesne/STT3220/SerieEnergie.txt';  
  input serie @@;
  temps = _n_;
run;

data energie;
  set serietxt;
  if temps <= 324;
run;


/*
proc print data=energie;
run;
*/

GOPTIONS RESET=ALL GACCESS='sasgastd > FigSerie.pdf'  DEVICE=PDF;
GOPTIONS FTEXT=ZAPF BORDER ROTATE=LANDSCAPE;
SYMBOL1 V=DOT H=.1 C=BLACK I=JOIN L=1; 
AXIS1 LABEL=('Temps');
AXIS2 LABEL=(a=90 'Serie');
PROC GPLOT DATA=energie;
  PLOT serie*temps=1;
TITLE "GRAPHIQUE DE LA SERIE ORIGINALE";
run; 

****************************************************************;
***********  Ajustement par moindres carres ********************;
****************************************************************;


proc reg data=energie;
 model serie = temps;
 plot (serie residual.)*temps;
 output out=fit1 residual=res predicted=predites;
run; 

GOPTIONS RESET=ALL GACCESS='sasgastd > fig1_energie.pdf'  DEVICE=PDF;
GOPTIONS FTEXT=ZAPF BORDER ROTATE=LANDSCAPE;
SYMBOL1 V=DOT H=.1 C=BLACK I=JOIN L=1; 
SYMBOL2 V=DOT H=.1 C=BLACK I=JOIN L=3;
AXIS1 LABEL=('Temps');
AXIS2 LABEL=(a=90 'Serie');
PROC GPLOT DATA=fit1;
  PLOT serie*temps=1 predites*temps=2 
       /overlay haxis=axis1 hminor=0 vaxis=axis2 vminor=0;
TITLE "AJUSTEMENT PAR MOINDRES CARRES";
run; 

GOPTIONS RESET=ALL GACCESS='sasgastd > fig2_energie.pdf'  DEVICE=PDF;
GOPTIONS FTEXT=ZAPF BORDER ROTATE=LANDSCAPE;
SYMBOL1 V=DOT H=.1 C=BLACK I=JOIN L=1; 
AXIS1 LABEL=('Temps');
AXIS2 LABEL=(a=90 'Residus');
PROC GPLOT DATA=fit1;
  PLOT res*temps=1  
       /overlay haxis=axis1 hminor=0 vaxis=axis2 vminor=0;
TITLE "GRAPHIQUE DES RESIDUS VERSUS LE TEMPS";
run; 

GOPTIONS RESET=ALL GACCESS='sasgastd > fig3_energie.pdf'  DEVICE=PDF;
GOPTIONS FTEXT=ZAPF BORDER ROTATE=LANDSCAPE;
SYMBOL1 V=DOT H=.1 C=BLACK I=JOIN L=1; 
AXIS1 LABEL=('Valeurs predites');
AXIS2 LABEL=(a=90 'Residus');
PROC GPLOT DATA=fit1;
  PLOT res*predites=1  
       /overlay haxis=axis1 hminor=0 vaxis=axis2 vminor=0;
TITLE "GRAPHIQUE DES RESIDUS VERSUS LES VALEURS PREDITES";
run; 


****************************************************************;
**************  Performance previsionnellle ********************;
****************************************************************;
data nouvelle;
 input temps;
datalines;
325 
326 
327 
328 
329 
330 
331 
332 
333 
;

data prevision;
 set energie nouvelle;
run;

proc reg data=prevision;
 model serie = temps;
 output out=fit2 residual=res predicted=predites;
run;

data perform;
  merge fit2 (drop= serie res) serietxt;
  if temps >= 325;
  erreur = (predites - serie)/serie;
run;

proc print data=perform;
run;

proc means data=perform;
  var erreur;
run;

ods pdf close;
****************************************************************;